Re: [boost] [1.58.0] Release candidates available

Subject: Re: [boost] [1.58.0] Release candidates available
From: Stephan T. Lavavej (stl_at_[hidden])
Date: 2015-04-06 14:34:46

[Klaim - Joël Lamotte]
> Although I didn't know that there was a parallel build option.

It's -j%NUMBER_OF_PROCESSORS% , like GNU make.

Here's my whole batch file, which auto-senses x86/x64.

:: ********** BEGIN build_boost.bat **********

@echo off
setlocal

set X_INPUT=boost_1_57_0
set X_OUTPUT=boost-1.57.0

if /i "%PLATFORM%"=="X64" set X_ADDRESS_MODEL=address-model=64
if /i "%PLATFORM%"=="X64" set X_OUTPUT=%X_OUTPUT%-x64

if not "%INCLUDE%"=="" goto good0
echo ERROR: This doesn't look like a Visual Studio Command Prompt.
goto :eof
:good0

if exist %X_INPUT%\bootstrap.bat goto good1
echo ERROR: %X_INPUT%\bootstrap.bat doesn't exist.
goto :eof
:good1

if not exist %X_OUTPUT% goto good2
echo ERROR: %X_OUTPUT% already exists.
goto :eof
:good2

pushd %X_INPUT%

call bootstrap.bat

if exist b2.exe goto good3
echo ERROR: bootstrap.bat failed to build b2.exe.
goto :eof
:good3

b2.exe -j%NUMBER_OF_PROCESSORS% %X_ADDRESS_MODEL% -q --build-type=complete --stagedir=..\%X_OUTPUT% stage

if "%ERRORLEVEL%"=="0" goto good4
echo ERROR: b2.exe failed to build Boost.
goto :eof
:good4

popd

mkdir %X_OUTPUT%\include

move %X_INPUT%\boost %X_OUTPUT%\include

rd /s /q %X_INPUT%

echo SUCCESS!

:: ********** END build_boost.bat **********

STL