@echo off

rem link= determines whether lib or dll files are built.
rem       static         builds lib files only
rem       shared         builds dll files only (with lib import libraries)
rem       static,shared  builds both
rem  Note that, by default, programs will link against the static libraries, regardless of this setting.
rem
rem runtime-link= determines which version of the C++ runtime will be used
rem       static         link against static (lib) runtime only
rem       shared         link against shared (dll) runtime only
rem       static,shared  link against both (this will double build time and nubmer of compiled libraries)
rem
rem threading=multi  Link against the multi-threaded runtime (Microsoft no longer produces any other kind)
rem
rem variant=debug,release  link against both debug and release libraries
rem
set VARIANTS=link=static runtime-link=static,shared threading=multi variant=debug,release


rem list compiler toolsets to build boost against
rem
set TOOLSETS=toolset=msvc-9.0 toolset=msvc-10.0


rem Configure libraries
rem
rem If you don't want to use zlib or bzip2 compression, then remove those options from this line.
set LIBRARY_OPTIONS=-sBZIP2_SOURCE="C:\Third_Party\bzip2-1.0.6" -sZLIB_SOURCE="C:\Third_Party\zlib-1.2.5"


rem Where the libraries should be installed
rem
set DESTINATION=C:\boost


rem End of configurable options.


set COMMON_ARGS=--prefix=%DESTINATION% %TOOLSETS% %VARIANTS% embed-manifest=on %LIBRARY_OPTIONS% -j%NUMBER_OF_PROCESSORS% install

set ARGS_64_BIT=--libdir=%DESTINATION%\lib64 address-model=64
set ARGS_32_BIT=--libdir=%DESTINATION%\lib32 address-model=32

call bootstrap.bat

.\bjam %ARGS_64_bit% %COMMON_ARGS%

del %DESTINATION%\lib64\*-mt.lib
del %DESTINATION%\lib64\*-sgd.lib
del %DESTINATION%\lib64\*-gd.lib
del %DESTINATION%\lib64\*-s.lib

.\bjam %ARGS_32_BIT% %COMMON_ARGS%

del %DESTINATION%\lib32\*-mt.lib
del %DESTINATION%\lib32\*-sgd.lib
del %DESTINATION%\lib32\*-gd.lib
del %DESTINATION%\lib32\*-s.lib