Re: [Boost-build] The state of WCE support in Boost

From: David Deakins (ddeakins_at_[hidden])
Date: 2008-08-20 16:02:20

Paul Heil wrote:
> Below is the my addition to my user-config.jam file that I based on the 
> VeecoFTC one.
> 
> using msvc : WM5 :
>     "cl.exe" :
>     <compileflags>-D_CRT_SECURE_NO_WARNINGS
>     <compileflags>-D_WIN32_WCE=0x501
>     <compileflags>-DUNDER_CE=0x501
>     <compileflags>-DWIN32_WCE_PSPC
>     <compileflags>-DWINCE
>     <compileflags>-DARM
>     <compileflags>-D_ARM_
>     <compileflags>-DARMV4I
>     <compileflags>-D_LITTLE_ENDIAN
>     <compileflags>-DUNICODE
>     <compileflags>-D_UNICODE
>     <compileflags>-DPOCKETPC2003_UI_MODEL   
>     <linkflags>/subsystem:windowsce,5.01
>     <linkflags>/machine:THUMB
>     <linkflags>/NODEFAULTLIB:oldnames.lib
>     <linkflags>/STACK:262144,4096
>     <linkflags>coredll.lib
>     <linkflags>corelibc.lib
>     <linkflags>ole32.lib
>     <linkflags>oleaut32.lib
>     <linkflags>uuid.lib
>     <linkflags>commctrl.lib
>     <architecture>arm
>     <instruction-set>armv4
>     <interface>wince
>     <assembler>"armasm.exe "
> ;
> 
> I've been using this command line to compile:
> bjam --without-python --without-mpi 
> msvc-WM5/variant=debug,release/threading=multi/stdlib=stlport/link=shared,static/runtime-link=static 
> stage
> 
> Obviously, I'm still missing something, though. Can you tell from this 
> what that is?
> 

One different that might matter is that you don't have the <setup> 
property to calls the appropriate VSVars32.bat file and make sure the 
correct compiler/linker tools are selected.  I noticed that I don't show 
the contents of our VSVars32.bat in the VeecoFTC config, so I attached 
our (VC9/STLport/WM5) batch file as an example.  Note that the batch 
file expects a VS9INSTALLDIR environment variable to indicate where 
Visual Studio 9.0 is installed.

Hopefully this gets you further,
-Dave


@SET VCINSTALLDIR=%VS9INSTALLDIR%\VC
@if "%VS9INSTALLDIR%"=="" goto error_no_VSINSTALLDIR
@if "%VCINSTALLDIR%"=="" goto error_no_VCINSTALLDIR

@echo Setting environment for using Microsoft Visual Studio 2008 tools for WM5.
@set TARGETCPU=X86

@call :GetWindowsSdkDir

@if not "%WindowsSdkDir%" == "" (
        set "PATH=%WindowsSdkDir%bin;%PATH%"
)

@rem
@rem Root of Visual Studio IDE installed files.
@rem
@set DevEnvDir=%VS9INSTALLDIR%\Common7\IDE

@set PATH=%VCINSTALLDIR%\CE\bin\x86_arm;%VCINSTALLDIR%\bin;%VS9INSTALLDIR%\Common7\Tools;%DevEnvDir%;%VS9INSTALLDIR%\Common\Tools;%VS9INSTALLDIR%\Common\IDE;%VS9INSTALLDIR%;%PATH%
@set INCLUDE=%STLPORT_PATH%\STLPort-5.1.5\stlport;%VCINSTALLDIR%\ce\include;%CETOOLS%\Windows Mobile 5.0 Pocket PC SDK\include\ARMV4I;%CETOOLS%\Windows Mobile 5.0 Pocket PC SDK\include;%VCINSTALLDIR%\ce\atlmfc\include
@set LIB=%STLPORT_PATH%\STLPort-5.1.5\lib\evc9-arm;%CETOOLS%\Windows Mobile 5.0 Pocket PC SDK\lib\ARMV4I;%VCINSTALLDIR%\ce\ATLMFC\LIB\ARMV4I;%VCINSTALLDIR%\ce\LIB\ARMV4I
@set LIBPATH=

@goto end

:GetWindowsSdkDir
@call :GetWindowsSdkDirHelper HKLM > nul 2>&1
@if errorlevel 1 call :GetWindowsSdkDirHelper HKCU > nul 2>&1
@if errorlevel 1 set WindowsSdkDir=%VCINSTALLDIR%\PlatformSDK\
@exit /B 0

:GetWindowsSdkDirHelper
@for /F "tokens=1,2*" %%i in ('reg query "%1\SOFTWARE\Microsoft\Microsoft SDKs\Windows" /v "CurrentInstallFolder"') DO (
        if "%%i"=="CurrentInstallFolder" (
                SET "WindowsSdkDir=%%k"
        )
)
@if "%WindowsSdkDir%"=="" exit /B 1
@exit /B 0

:error_no_VSINSTALLDIR
@echo ERROR: VS9INSTALLDIR variable is not set. 
@goto end

:error_no_VCINSTALLDIR
@echo ERROR: VCINSTALLDIR variable is not set. 
@goto end

:end