Re: [Boost-testing] Some outdated pages

From: Rene Rivera (grafik.list_at_[hidden])
Date: 2005-05-04 00:36:06

JOAQUIN LOPEZ MU?Z wrote:
> Hello, I noticed that the inspection report
> and the unresolved issues page
> 
> http://www.boost.org/regression-logs/inspection_report.html
> http://www.meta-comm.com/engineering/boost-regression/cvs-
> head/developer/issues.html
> 
> do not appear to be updating since quite some time.

Yep.. I haven't run them in a really long time. Actually the machine I 
run them from is my desktop and it's become somewhat unstable when doing 
CVS updates, long story. And the replacement machine gets to me, in 
pieces, tomorrow. So I won't be able to run them again until the weekend.

Of course if other want to run them that would be cool ;-)

Attached is the batch file I use to run them. Eventually I'll put this 
into the buildbot but that's for after 1.33.

-- 
-- Grafik - Don't Assume Anything
-- Redshift Software, Inc. - http://redshift-software.com
-- rrivera/acm.org - grafik/redshift-software.com
-- 102708583/icq - grafikrobot/aim - Grafik/jabber.org

@ECHO OFF

REM ~ # Set the following variables to configure the operation. Variables you
REM ~ # should set, i.e. usually required are listed first. Optional variables
REM ~ # have reasonable defaults for most situations.

REM ~ ### THESE SHOULD BE CHANGED!

REM ~ #
REM ~ # "boost_root" points to the root of you boost installation:
REM ~ # This can be either a non-exitent directory or an already complete Boost
REM ~ # source tree.
REM ~ #
set boost_root=C:\CVSROOTs\Boost\boost

REM ~ #
REM ~ # "toolset" is the Boost.Build toolset to use for building the helper programs.
REM ~ # This is usually different than the toolsets one is testing. And this is
REM ~ # normally a toolset that corresponds to the compiler built into your platform.
REM ~ #
set toolset=vc-7_1

REM ~ ### DEFAULTS ARE OK FOR THESE.

REM ~ #
REM ~ # "exe_suffix" the suffix used by exectable files:
REM ~ # In case your platform requires use of a special suffix for executables specify
REM ~ # it here, including the "." if needed. This should not be needed even in Windows
REM ~ # like platforms as they will execute without the suffix anyway.
REM ~ #
set exe_suffix=.exe

REM ~ #
REM ~ # "bjam" points to your built bjam executable:
REM ~ # The location of the binary for running bjam. The default should work
REM ~ # under most circumstances.
REM ~ #
set bjam=%boost_root%\tools\build\jam_src\bin\bjam%exe_suffix%

REM ~ #
REM ~ # "boost_build_path" can point to additional locations to find toolset files.
REM ~ #
set boost_build_path=%HOME%\.boost-build

REM ~ ### NO MORE CONFIGURABLE PARTS.

REM ~ #
REM ~ # Some setup.
REM ~ #
set BOOST_BUILD_PATH=%boost_build_path% %BOOST_BUILD_PATH%
set ALL_LOCATE_TARGET=C:\Boost\regression
set PYTHON_ROOT=C:\Python22
set PYTHON_VERSION=2.2
set BUILD=release
set MINGW_ROOT_DIRECTORY=C:\MinGW
set PATH=C:\MinGW\bin;C:\Program Files\GnuWin32\bin;%PATH%
set inspect=%ALL_LOCATE_TARGET%\tools\inspect\build\run\inspect%exe_suffix%

REM ~ #
REM ~ # rebuild bjam if required:
REM ~ #
echo building bjam:
cd %boost_root%\tools\build\jam_src
set LOCATE_TARGET=bin
setlocal & endlocal
call .\build.bat
@ECHO OFF
if errorlevel 1 goto :eof
REM ~ call .\build.bat mingw

REM ~ #
REM ~ # rebuild the helper programs if required:
REM ~ #
echo building helper programs:
cd %boost_root%\tools\inspect\build
%bjam% -sTOOLS=%toolset% -sBUILD=release run
if errorlevel 1 goto :eof

cd %boost_root%
REM ~ cd %boost_root%\tools\inspect

REM ~ #
REM ~ # run the tests:
REM ~ #
echo running inspect tests:
%inspect% -cvs -crlf -link -long_name -tab -minmax > %ALL_LOCATE_TARGET%\inspection_report.html
%inspect% -cvs -copyright -license > %ALL_LOCATE_TARGET%\license_report.html

REM ~ #
REM ~ # publish the result:
REM ~ #
echo publish the result:
cd %ALL_LOCATE_TARGET%
c:\Bin\scp.exe -S C:\Bin\ssh.exe inspection_report.html "grafik_at_[hidden]:/home/groups/b/bo/boost/htdocs/regression-logs/inspection_report.html"
if errorlevel 1 goto :eof
c:\Bin\scp.exe -S C:\Bin\ssh.exe license_report.html "grafik_at_[hidden]:/home/groups/b/bo/boost/htdocs/regression-logs/license_report.html"
if errorlevel 1 goto :eof

echo "done!"